Daggerfall Mod:BIOG??T0.TXT Files/File Format

File Format

The format in Augmented BNF follows:

SP = %x20
HTAB = %x09
CR = %x0D
LF = %x0A
CRLF = CR LF

DIGIT = %x30-39
ALPHA = %x41-5A / %x61-7A
BANG = %x21
POUND = %x23

DOT = %x2E

SIGN = "+" / "-"
SignedAmount = Sign 1*DIGIT
UnsignedAmount = 1*DIGIT

BiographyText = 4*DIGIT ; must be a valid TextRecordId in TEXT.RSC
BiographyCommand = ( POUND / BANG ) BiographyText 

SkillNumber = ( [ %x31-32 ] DIGIT ) / ( %x33 %x30-34 )
SkillCommand = SkillNumber SP SignedAmount

DemographicPrefix = "r" %x30-34
FactionPrefix = "rf" 1*DIGIT
ReactionRollPrefix = "RR"
ReputationCommand = ( DemographicPrefix / FactionPrefix / ReactionRollPrefix ) SP SignedAmount

ResistPoisonPrefix = "RP"
ResistDiseasePrefix = "RD"
ResistMagicPrefix = "MR"
ResistanceCommand = ( ResistPoisonPrefix / ResistDiseasePrefix / ResistMagicPrefix ) SP SignedAmount

GoldPiecesCommand = "GP" SP SignedAmount

ItemPrefix = "IT"
ArbitraryItemCoordinate = CoordinateX SP CoordinateY SP CoordinateZ
CoordinateX = 1*DIGIT
CoordinateY = 1*DIGIT
CoordinateZ = 1*DIGIT
ItemCommand = ItemPrefix SP ArbitraryItemCoordinate

ToHitCommand = "TH" SP SignedAmount
FatigueCommand = "FT" SP SignedAmount

Command = HTAB ( SkillCommand / ReputationCommand / ResistanceCommand / GoldPiecesCommand / ItemCommand )
CommandList = Command *( CRLF Command )
AnswerChar = %x20-7E ; any printable ASCII character, including space
AnswerText = 1*AnswerChar ; the maximum length will be verified presently
Answer = AnswerText CRLF CommandList CRLF